[宏][狂暴][武器][PVE][PVE] 让人人都开的起自动档，自动姿态/强效致死/无忧回复/智能援护 [全键无冲突]

开了几年自动档战士了，给大家分享下，可以做到动作条上完全不用且姿态按键。

如果有些宏有bug可以在评论区提出。
[h]以下是宏和对应的效果[/h]

一键冲锋/猛击远射复合宏
#showtooltip [combat]猛击;冲锋
/castsequence [combat] reset=target,1 猛击,英勇打击
/cast [combat] 狂暴姿态;[stance:1,@mouseover,exists][stance:1] 冲锋;[stance:2/3] 战斗姿态
/startattack
/施放 !射击
/stopmacro [nocombat]
/施放 [stance:3]  血性狂暴
效果：
1. 起手没在战斗中，直接冲锋。
2. 进入战斗之后，继续按会自动切成狂暴姿态。后续按这个技能会变成猛击，所以战斗中猛击亮了同样可以按这个。
3. 距离远了之后会自动切成射击状态
4. 当成功释放一个猛击后，再继续按会附带一个英勇打击(在怒气多的时候死命按就完事了)
这个宏因为战斗和非战斗技能是互斥的，所以非常好用，近距离猛击，远距离射击，非战斗可以冲锋自动切狂暴姿态，战斗中可以血性狂暴打猛击。


双天赋强效致死/嗜血二合一宏
#showtooltip [spec:1] 嗜血;[spec:2]致死打击
/castsequence [spec:1] reset=1,target 嗜血,英勇打击;[spec:2] reset=1,target 致死打击,英勇打击
/cast [combat,stance:1/3] 血性狂暴
/cast !射击
/cast !投掷
/startattack
/use 10
效果：
1. 天赋1用嗜血，天赋2用致死，主要是为了节省宏数量
2. 强效嗜血和强效致死一个原理，按一次放嗜血，放出去了之后再按，会带上一个英勇打击，避免浪费怒气，比如怒气低的时候，就一下一下按，怒气多就快速按
3. 如果距离不够会自动进行射击/投掷
4. 自动开手套加速器
(在怒气多的时候死命按就完事了)

无忧旋风斩宏
#showtooltip 旋风斩
/equipslot 17 人性的背叛者
/equipslot 16 风暴符文剑
/cast [nostance:3]狂暴姿态
/cast [combat] 血性狂怒(种族特长)
/CAST [stance:3,combat] 血性狂暴
/use [combat] 13
/use [combat] 14
/use [combat] 19
/cast [stance:3] 旋风斩
/startattack
效果：
1. 自动换上双手武器、自动切姿态放旋风斩
2. 会先判断是否在狂暴姿态在进行血性狂暴
3. 避免饰品误开，会在战斗中饰品全开

爆炸诱饵宏
工程学的话可以使用一分钟一次的爆炸诱饵，但是腰带要附魔电磁脉冲发生器
#showtooltips 爆炸诱饵
/castsequence [@player] reset=10 爆炸诱饵,6
效果：
1. 自动在原地脚下放一个爆炸诱饵
2. 自动使用腰带触发爆炸
AOE贼好用

原地炸弹宏
同理，因为战士大部分近战aoe，所以炸弹放脚下最好
#showtooltip
/cast [@player] 萨隆邪铁炸弹
效果：
在脚下放一个炸弹，避免还要鼠标点选位置

远程扔炸弹
当然，如果你是LR等远程职业，可以在鼠标指向位置仍炸弹，这样可以少点一次鼠标
#showtooltip
/cast [@cursor] 萨隆邪铁炸弹

顺劈/英勇自动换武器宏
#showtooltip 顺劈斩
/equipslot 17 人性的背叛者
/equipslot 16 风暴符文剑
/cast 顺劈斩
/cast 乘胜追击
这个宏的目的主要还是为了换武器，比如切盾盾反之后，按一下，虽然技能没打出去但是武器换成功了。

无忧狂怒回复宏
是不是经常想要用怒气回血的是时候技能不亮？是因为没有激怒效果
#showtooltip 狂怒回复
/CAST 狂怒回复
/castsequence reset=1 狂暴之怒,狂怒回复
/cast 血性狂暴
效果：
1. 先开狂暴之怒产生激怒效果，然后使用狂怒回复
2. 为了避免怒气不够，会自动释放血性狂暴增加回复量

不切目标援护宏
#showtooltip 援护
/cast [nostance:2] 防御姿态; [@mouseover,help] 援护;[help] 援护;[target=targettarget, help] 援护
/startattack [target=harm]
效果：
1. 如果不在防御姿态则先切姿态
2. 如果有鼠标指向就援护指向，否则就援护当前目标
3. 如果当前目标为敌对，就援护他在看的队友
特点：
想援护一直按就行了。不切目标的话，会援护目标的目标，并且不会打断攻击

为什么不和冲锋绑到一起？
有朋友想吧援护和冲锋绑一起，但绑到一起会有两个问题：
1. 当目标是一个敌对目标，并且他在看队友的时候，宏无法区分是冲锋他，还是援护他看的队友。
2. 如果冲锋敌人之前，敌人忽然切目标看队友，可能会导致宏判断要援护队友。
所以不推荐这么做。

盾反不换盾宏
#showtooltip 法术反射
/stopcasting
/equipslot [noequipped:盾牌]17 血神徽记
/施放 [stance:1/2] 法术反射;防御姿态
/施放 [stance:1/2,equipped:盾牌] 血性狂暴
/startattack
/cast !射击
说明： [noequipped:盾牌] 的原因是如果当前带着盾，但名字不一样，可能会产生换盾的动作，产生 1.5s GCD，所以带着盾的时候就不切了。
效果：被法师冰环可以不停的按，还会射箭

雷霆挫志宏
#showtooltips
/castsequence [stance:1/2] reset=4 雷霆一击,挫志怒吼; [stance:3] reset=2 挫志怒吼,战斗姿态,雷霆一击
用法：碰到近战就不停的按
效果：不管在什么姿态都能'最小怒气浪费'的依次上好雷霆和挫志。
场景：和近战对砍，先不停地按上好debuff

冲锋断筋远射宏
#showtooltip 拦截
/equipslot [stance:3]16 萨弗拉斯，炎魔拉格纳罗斯之手
/CAST [stance:3] 断筋
/CAST [stance:3] 拦截; 狂暴姿态
/CAST [stance:3,combat] 血性狂暴; 狂暴姿态
/startattack
/cast !射击
效果：切姿态拦截到目标脚下并断筋，并血性狂暴加怒。一般来说到目标脚下就有30怒，可以直接致死，目标身上还挂着断筋。
效果2：如果被迫拦截法师，法师冰环走远，继续死命按，会直接远射，远射能打退施法，按到冰环消失会直接进行拦截并进行自动攻击。
(一般被冰环之后怒气会溢出，还可以加上英勇)
场景：见到法师先冲锋，如果法师冰环，请一直按，会进行远程射击，按到冰环消失会再次发起拦截

拳击盾击宏
#showtooltip [stance:3] 拳击; [nostance:3, equipped:盾牌] 盾击; [nostance:3, noequipped:盾牌] 拳击
/stopcasting
/cast [stance:3] 拳击
/cast [nostance:3, equipped:盾牌] 盾击
/cast [nostance:3, noequipped:盾牌] 狂暴姿态
/cast [nostance:3, noequipped:盾牌] 拳击
效果：如果当前在狂暴会释放拳击打断；如果不在狂暴姿态但带着盾牌，会施放盾击打断；如果盾牌都没带会切狂暴并施放拳击打断。
(为什么没设定防御姿态直接切盾放盾击？因为战斗中切盾有1.5S gcd ，不如直接切狂暴打断)

强效致死远射宏
#showtooltip 致死打击
/equipslot 16 萨弗拉斯，炎魔拉格纳罗斯之手
/castsequence reset=1 致死打击,!英勇打击
/startattack
/cast !射击
效果：带上双手装备(可能开始带着盾)放致死，如果有怒，并且放出去了致死，会继续放英勇。
效果2：如果砍法师，法师可能冰环闪现，这个时候可以立马按出远射，远射可以打退寒冰箭。


其他的一些 TIPS：
有些宏可能会这么写
/CAST 致死打击
/CAST 英勇打击
这样是有问题的，因为如果致死没放出去(比如距离远了)，会导致下次靠近一直先放英勇，造成怒气浪费，影响下次技能释放。
/castsequence reset=1 致死打击,!英勇打击
这样就不会有问题，会一定先保证致死放出，有多余的怒气才会放英勇,并且英勇如果一直没打上，会继续重置到致死，避免怒气浪费。


其他需求可以在评论区提出，有时间帮大家实现。
有朋友反馈援护宏不好使，我猜可能是因为距离不够的时候，图标没警示导致，所以加上图标展示判断
#showtooltips [nostance:2] 援护; [@mouseover,help]援护;[help] 援护;[@targettarget, help] 援护;援护
/cast [nostance:2] 防御姿态; [@mouseover,help]援护;[help] 援护;[@targettarget, help] 援护;援护
/startattack [@target,harm]

留个名，60年代的战士捡起来

好帖留名

好帖，留爪
我还是个手动挡小白，都没怎么用过宏

立马回家叮一个战士

插个眼👁

好好好，资瓷一下，打好基础是战士区重新繁荣的必经之路

所以，宏里的60年代武器名字的改成现在自己带的武器？

好帖留名

深入学习宏知识，做新时代的强力战士